Commit 82890d13 authored by John van Groningen's avatar John van Groningen Committed by Camil Staps

move module StdMaybe from StdLib to StdEnv

parent 6c308baa
definition module StdMaybe
// ********************************************************************************
// Clean StdLib library module, version 1.0
// ********************************************************************************
from StdOverloaded import class ==(..);
:: Maybe x
= Just x
| Nothing
isJust :: !(Maybe .x) -> Bool // case @1 of (Just _) -> True; _ -> False
isNothing :: !(Maybe .x) -> Bool // not o isJust
fromJust :: !(Maybe .x) -> .x // \(Just x) -> x
// for possibly unique elements:
isJustU :: !u:(Maybe .x) -> (!Bool, !u:Maybe .x)
isNothingU :: !u:(Maybe .x) -> (!Bool, !u:Maybe .x)
mapMaybe :: .(.x -> .y) !(Maybe .x) -> Maybe .y
// mapMaybe f (Just x) = Just (f x)
// mapMaybe f Nothing = Nothing
instance == (Maybe x) | == x
// Nothing==Nothing
// Just a ==Just b <= a==b
maybeToList :: !(Maybe .a) -> [.a];
// returns list with no or one element
listToMaybe :: ![.a] -> .Maybe .a;
// returns Just head of list if possible
catMaybes :: ![Maybe .a] -> .[.a];
// catMaybes ms = [ m \\ Just m <- ms ]
implementation module StdMaybe
// ********************************************************************************
// Clean StdLib library module, version 1.0
// ********************************************************************************
from StdOverloaded import class ==(..);
:: Maybe x
= Just x
| Nothing
isJust :: !(Maybe .x) -> Bool
isJust Nothing = False
isJust _ = True
isNothing :: !(Maybe .x) -> Bool
isNothing Nothing = True
isNothing _ = False
isJustU :: !u:(Maybe .x) -> (!Bool, !u:Maybe .x)
isJustU nothing=:Nothing
= (False, nothing)
isJustU just
= (True, just)
isNothingU :: !u:(Maybe .x) -> (!Bool, !u:Maybe .x)
isNothingU nothing=:Nothing
= (True, nothing)
isNothingU just
= (False,just)
fromJust :: !(Maybe .x) -> .x
fromJust (Just x) = x
mapMaybe :: .(.x -> .y) !(Maybe .x) -> Maybe .y
mapMaybe f (Just x) = Just (f x)
mapMaybe _ nothing = Nothing
instance == (Maybe x) | == x where
(==) Nothing maybe = case maybe of
Nothing -> True
just -> False
(==) (Just a) maybe = case maybe of
Just b -> a==b
nothing -> False
maybeToList :: !(Maybe .a) -> [.a];
maybeToList Nothing = []
maybeToList (Just a) = [a]
listToMaybe :: ![.a] -> .Maybe .a;
listToMaybe [] = Nothing
listToMaybe [a:_] = Just a
catMaybes :: ![Maybe .a] -> .[.a];
catMaybes ms = [ m \\ Just m <- ms ]
Markdown is supported
0% or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment